trixy/trixy-parser/docs/grammar.ebnf

#(*
# Copyright (C) 2023  The Trinitrix Project <soispha@vhack.eu, antifallobst@systemausfall.org>
#
# This file is part of the Trixy crate for Trinitrix.
#
# Trixy is free software: you can redistribute it and/or modify
# it under the terms of the Lesser GNU General Public License as
# published by the Free Software Foundation, either version 3 of
# the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# and the Lesser GNU General Public License along with this program.
# If not, see <https://www.gnu.org/licenses/>.
#*)


# (*
# Trixy is fully whitespace independent, this means that you can
# interleave whitespace in the definitions.
#  The same applies to comments:
#  - Line comments (`// \n`) and
#  - Block comments (`/* */`).
# *)

CommandSpec = {Function | Namespace | Enumeration | Structure } ;

Function = {DocComment} "fn" Identifier "(" [NamedType {"," NamedType }] ")" [ "->" Type ] ";" ;
Namespace = {DocComment} "mod" Identifier "{" {Function | Namespace | Enumeration | Structure} "}" ;
Structure = {DocComment} "struct" Identifier "{"  [DocNamedType {"," DocNamedType } [","]] "}";
Enumeration = {DocComment} "enum" Identifier "{"  [DocIdentifier {"," DocIdentifier} [","]] "}";

Type = Identifier ["<" Type {"," Type} ">"];

Identifier = (CHARACTER | "_") { NUMBER | CHARACTER | "_" } ;
DocIdentifier = {DocComment} (CHARACTER | "_") { NUMBER | CHARACTER | "_" } ;

NamedType = Identifier ":" Type;
DocNamedType = {DocComment} Identifier ":" Type;


DocComment = "///" {ANYTHING} LineEnding;

Comment = "//" [ NOT ("/" {ANYTHING} LineEnding) | "//"] {ANYTHING} LineEnding;
LineEnding = "\\n" | "\\r" | "\\r\\n";

# (*
#  vim: ft=ebnf
# *)