trixy/c_test/flake.nix

# Copyright (C) 2023 - 2024:
# The Trinitrix Project <soispha@vhack.eu, antifallobst@systemausfall.org>
# SPDX-License-Identifier: LGPL-3.0-or-later
#
# This file is part of the Trixy crate for Trinitrix.
#
# Trixy is free software: you can redistribute it and/or modify
# it under the terms of the Lesser GNU General Public License as
# published by the Free Software Foundation, either version 3 of
# the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# and the Lesser GNU General Public License along with this program.
# If not, see <https://www.gnu.org/licenses/>.
{
  description = "[can be empty]";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };

    flake_version_update = {
      url = "git+https://codeberg.org/soispha/flake_version_update.git";
      inputs = {
        systems.follows = "systems";
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };

    # inputs for following
    systems = {
      url = "github:nix-systems/x86_64-linux"; # only evaluate for this system
    };
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };
    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs = {
        systems.follows = "systems";
      };
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    treefmt-nix,
    flake_version_update,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = nixpkgs.legacyPackages."${system}";

      nativeBuildInputs = with pkgs; [valgrind pandoc];
      treefmtEval = import ./treefmt.nix {inherit treefmt-nix pkgs;};

      # This version is set automatically on `cog bump --auto`;
      version = "v0.1.0"; # GUIDING VERSION STRING
      pname = "c_test";

      build = pkgs.stdenv.mkDerivation {
        inherit pname version;

        src = ./.;
        makeFlags = ["PREFIX=${placeholder "out"}" "BIN_VERSION=${version}"];
        inherit nativeBuildInputs;
      };
    in {
      packages.default = build;
      checks = {
        inherit build;
        formatting = treefmtEval.config.build.check self;
      };
      formatter = treefmtEval.config.build.wrapper;

      devShells.default = pkgs.mkShell {
        packages = with pkgs; [
          cocogitto
          flake_version_update.packages."${system}".default

          licensure
        ];
        inherit nativeBuildInputs;
        env = {
          GCC_COLORS = "error=01;31:warning=01;35:note=01;36:caret=01;32:locus=01:quote=01";
        };
      };
    });
}
# vim: ts=2