core/flake.nix

{
  description = "A terminal UI client for the matrix chat protocol";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    # inputs for following
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };
    crane = {
      url = "github:ipetkov/crane";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs = {};
    };
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
  };

  outputs = {
    self,
    nixpkgs,
    crane,
    flake-utils,
    rust-overlay,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      inherit (pkgs) lib;
      bintools-wrapper = "${nixpkgs}/pkgs/build-support/bintools-wrapper";
      mold' = pkgs.symlinkJoin {
        name = "mold";
        paths = [pkgs.mold];
        nativeBuildInputs = [pkgs.makeWrapper];
        suffixSalt = lib.replaceStrings ["-" "."] ["_" "_"] pkgs.targetPlatform.config;
        postBuild = ''
          for bin in ${pkgs.mold}/bin/*; do
            rm $out/bin/"$(basename "$bin")"

            export prog="$bin"
            substituteAll "${bintools-wrapper}/ld-wrapper.sh" $out/bin/"$(basename "$bin")"
            chmod +x $out/bin/"$(basename "$bin")"

            mkdir -p $out/nix-support
            substituteAll "${bintools-wrapper}/add-flags.sh" $out/nix-support/add-flags.sh
            substituteAll "${bintools-wrapper}/add-hardening.sh" $out/nix-support/add-hardening.sh
            substituteAll "${bintools-wrapper}/../wrapper-common/utils.bash" $out/nix-support/utils.bash
          done
        '';
      };
      pkgs = import nixpkgs {
        inherit system;
        overlays = [(import rust-overlay)];
      };

      nightly = true;
      rust =
        if nightly
        then
          (pkgs.rust-bin.selectLatestNightlyWith (toolchain:
              toolchain.default))
          .override {
            extensions = ["rustc-codegen-cranelift-preview"];
          }
        else pkgs.rust-bin.stable.latest.default;

      craneLib = (crane.mkLib pkgs).overrideToolchain rust;

      nativeBuildInputs = with pkgs; [
        pkg-config
        mold'
      ];
      buildInputs = with pkgs; [
        openssl
        lua54Packages.lua
      ];

      craneBuild = craneLib.buildPackage {
        src = craneLib.cleanCargoSource ./.;

        doCheck = true;
        inherit nativeBuildInputs buildInputs;
      };
    in {
      packages = {
        default = craneBuild;
      };

      app.default = {
        type = "app";
        program = "${self.packages.${system}.default}/bin/trinitix";
      };

      devShells.default = pkgs.mkShell {
        packages = with pkgs; [
          nil
          alejandra
          statix
          ltex-ls

          rust
          rust-analyzer
          cargo-edit
          cargo-expand
        ];
        inherit nativeBuildInputs buildInputs;
      };
    });
}
# vim: ts=2