# Copyright (C) 2024 - 2024:
# The Trinitrix Project <bpeetz@b-peetz.de, antifallobst@systemausfall.org>
# SPDX-License-Identifier: MIT
#
# This file is part of Trinitrix.
#
# Permission is hereby granted, free of charge, to any person
# obtaining a copy of this software and associated documentation files
# (the “Software”), to deal in the Software without restriction,
# including without limitation the rights to use, copy, modify, merge,
# publish, distribute, sublicense, and/or sell copies of the Software,
# and to permit persons to whom the Software is furnished to do so,
# subject to the following conditions:
#
# The above copyright notice and this permission notice shall be
# included in all copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND,
# EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
# OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
# NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
# HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
# WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
# FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
# OTHER DEALINGS IN THE SOFTWARE.
{
  description = "A multi protocol chat client";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };

    crane = {
      url = "github:ipetkov/crane";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };

    # inputs for following
    systems = {
      url = "github:nix-systems/x86_64-linux"; # only evaluate for this system
    };
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };
    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs = {
        systems.follows = "systems";
      };
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    treefmt-nix,
    crane,
    rust-overlay,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = import nixpkgs {
        inherit system;
        overlays = [(import rust-overlay)];
      };

      nightly = false;
      rust_minimal =
        if nightly
        then
          (pkgs.rust-bin.selectLatestNightlyWith (toolchain: toolchain.minimal)).override {
            extensions = ["rustc-codegen-cranelift-preview"];
          }
        else pkgs.rust-bin.stable.latest.minimal;
      rust_default =
        if nightly
        then
          (pkgs.rust-bin.selectLatestNightlyWith (toolchain: toolchain.default)).override {
            extensions = ["rustc-codegen-cranelift-preview"];
          }
        else pkgs.rust-bin.stable.latest.default;

      nativeBuildInputs = with pkgs; [
        pkg-config
        mold-wrapped

        clang-tools
      ];
      buildInputs = with pkgs; [
        openssl
        lua54Packages.lua
      ];

      cargo_toml = craneLib.cleanCargoToml {cargoToml = ./Cargo.toml;};
      pname = cargo_toml.package.name;

      craneLib = (crane.mkLib pkgs).overrideToolchain rust_minimal;
      craneBuild = craneLib.buildPackage {
        inherit nativeBuildInputs buildInputs;

        src = craneLib.cleanCargoSource ./.;

        doCheck = true;
      };

      manual = pkgs.stdenv.mkDerivation {
        name = "${pname}-manual";
        inherit (cargo_toml.package) version;

        src = ./docs;
        nativeBuildInputs = with pkgs; [pandoc];

        buildPhase = ''
          mkdir --parents $out/docs;

          pandoc "./${pname}.1.md" -s -t man > $out/docs/${pname}.1
        '';

        installPhase = ''
          install -D $out/docs/${pname}.1  $out/share/man/man1/${pname};
        '';
      };

      treefmtEval = import ./treefmt.nix {inherit treefmt-nix pkgs;};
    in {
      packages.default = pkgs.symlinkJoin {
        inherit (cargo_toml.package) name;

        paths = [manual craneBuild];
      };

      checks = {
        inherit craneBuild;
        formatting = treefmtEval.config.build.check self;
      };

      formatter = treefmtEval.config.build.wrapper;

      devShells.default = pkgs.mkShell {
        packages = with pkgs; [
          cocogitto

          yq

          rust_default
          cargo-edit

          valgrind
          licensure
        ];
        inherit nativeBuildInputs buildInputs;
      };
    });
}
# vim: ts=2